Inv Management problem

Here is bit of code that is driving me nuts [some debug left in]

It is supposed to delete all scripts in a prim, then delete itself.

What it does is delete 4, then stop. When it reaches i=4, the length of the name is 0 and it exits the loop and kills itself. The trace prints say what I expect except the scripts it does delete are not in alpha order [llGetInventoryName, says it should return in alpha order not that I care]

Leaving 2 scripts.

Anybody have a clue what I've messed up, debug trace at end of post

================================================

default
{
state_entry
{
integer i;
string name;
string ServerScript;
integer NameSize = 1;

ServerScript = llGetScriptName();
llSay(0, "Script name = "+ServerScript);

for (i=0;NameSize > 0; i++)
{
name = llGetInventoryName(INVENTORY_SCRIPT, i);
NameSize = llStringLength(name);
llSay(0," Index = "+(string)i+" Size = "+(string)NameSize);
if ((llStringLength(name) > 0) && (name != ServerScript))
{
llSay(0, "Deleting Script = "+name);
llRemoveInventory(name);
}
}
llSay(UpdateChan, "Purged";
llRemoveInventory("Purge";
}
}

=========================================

Script name = Purge
Index = 0 Size = 16
Deleting Script = AvController 4.1
Index = 1 Size = 21
Deleting Script = AvScannerDomestic 4.0
Index = 2 Size = 16
Deleting Script = Configurator 4.1
Index = 3 Size = 17
Deleting Script = Show Coverage 2.0
Index = 4 Size = 0

Wouldn't i at some point exceed the number of inventory script items as they are being deleted as you cycle through the loop?

So i is relative to the number of scripts when you make the call &^****%%$###

dang it, thank you

I kinda like this style:

integer nScripts = llGetInventoryNumber(INVENTORY_SCRIPT);
string thisScript = llGetScriptName();
string firstScript = llGetInventoryName(INVENTORY_SCRIPT, 0);
while (firstScript != thisScript)
{
    llRemoveInventory(firstScript);
    --nScripts;
    firstScript = llGetInventoryName(INVENTORY_SCRIPT, 0);
}
while (nScripts > 1)
{
    llRemoveInventory(llGetInventoryName(INVENTORY_SCRIPT, 1));
    --nScripts;
}
llRemoveInventory(thisScript);

Do the deletion loop backwards and you'll get something that is made of win.

A.k.a. Count down.

or build a list of items, remove your own script from that list, then loop through deleting them, then delete your script

Just for illustration. This is the code Squirrel Wood had in mind.

integer n = llGetInventoryNumber(INVENTORY_SCRIPT);
string thisScript = llGetScriptName();
while (n--)
{
string nthScript = llGetInventoryName(INVENTORY_SCRIPT, n);
if(nthScript != thisScript) llRemoveInventory(nthScript);
}
llRemoveInventory(thisScript);

Thanks for the help.

After the slap around the head, it was no problem. I had spent the day doing database programming in RL and was thinking SQL not LSL