Using llSetLinkTexture correctly

I have a linked set of objects that I want to set the texture of.

At the moment I have a script in each object that I need the texture to change listening for a link_message event, triggered by a llMessageLinked (LINK_SET) call in my main script.

This seems pretty inefficient, and I would like to use the llSetLinkTexture instead.

My question is, how to use this function to set the texture of all the linked objects, apart from two of them, neither of which is the root prim.

At the moment, I'm thinking I will have to get the link numbers of all the prims I need to change the texture of, and work through them using a 'for' loop.

Any suggestions welcome!

Thanks.

you just answered your own question lol.
you can also use the link name if the names of the child prims won't matter, IE;

default
{
    state_entry()
    {
        string texture = llGetInventoryName(INVENTORY_TEXTURE,0);
        integer num = llGetNumberOfPrims();
        for(num;num > 0;--num)
        {
            if(llToLower(llGetLinkName(num)) == "texture me")
            {
                llSetLinkTexture(num,texture,ALL_SIDES);
            }
        }
    }
}

You could also use the Description field in each child prim to carry flags that tell the parent what it's allowed to do to the prim. Building on Ruthven's example, here's a script that will let you read multiple flags from each child's Description field and then apply your choice of textures and alpha to selected ones at run time. You could set each child's description to "texture" or "alpha" or "texture alpha" to determine which changes to make when you say the key message.

integer CHAN = 33;
default
{
	state_entry()
	{
		llListen(CHAN,"",llGetOwner(),"");
	}
	listen(integer channel, string name, key id, string message)
	{
		integer num = llGetNumberOfPrims();
		for(num;num > 0;--num)
		{
			if(llListFindList((llGetObjectDetails(llGetLinkKey(num),[OBJECT_DESC]) ),["texture"]) != -1)
			{
					if (llToLower(message) == "texture1") //Apply "texture1"
					{
						llSetLinkTexture(num,"texture1",ALL_SIDES);
					}
					else if (llToLower(message) == "texture2") //Apply "texture2"
					{
						llSetLinkTexture(num,"texture2",ALL_SIDES);
					}
				}
				else if (llListFindList((llGetObjectDetails(llGetLinkKey(num),[OBJECT_DESC]) ), ["alpha"]) != -1)
				{
					if (llToLower(message) == "alphaoff") // Make the child visible
					{
						llSetLinkAlpha(num, 1.0,ALL_SIDES);
					}
					else if (llToLower(message) == "alphaon") // Make the child invisible
					{
						llSetLinkAlpha(num,0.0,ALL_SIDES);
					}
				}
			}
		}
}

OK... Here's a more complicated script based on Ruthven's. It reads flags from each linked prim's Description field and then, if it sees the right flags, responds to your command on channel 33. In this simple example, the allowed flags are "alpha" and "texture." You can type either one in the Description field of a prim, or neither, or both. If you type both, they must be separated by a comma. A chat command can turn alpha on or off on the identified prims, and can texture identified prims with either of the possible textures (assuming that they're in inventory).

I've tested this script in world and it works well. Question for a more adept scripter..... Is there a cleaner way for me to split out multiple flags from the Description field? My way works OK, but it looks clunky.

integer CHAN = 33;
default
{
    state_entry()
    {
        llListen(CHAN,"",llGetOwner(),"");
    }
    listen(integer channel, string name, key id, string message)
    {
        integer num = llGetNumberOfPrims();
        for(num;num > 0;--num)
        {
            list desc = llParseString2List(llList2String(llGetObjectDetails(llGetLinkKey(num),[OBJECT_DESC]),0),[","],[""]);
            if(llListFindList(desc,["texture"]) != -1)
            {
                    if (llToLower(message) == "texture1") //Apply "texture1"
                    {
                        llSetLinkTexture(num,"texture1",ALL_SIDES);
                    }
                    else if (llToLower(message) == "texture2") //Apply "texture2"
                    {
                        llSetLinkTexture(num,"texture2",ALL_SIDES);
                    }
                }
                if (llListFindList(desc, ["alpha"]) != -1)
                {
                    if (llToLower(message) == "alphaoff") // Make the child visible
                    {
                        llSetLinkAlpha(num, 1.0,ALL_SIDES);
                    }
                    else if (llToLower(message) == "alphaon") // Make the child invisible
                    {
                        llSetLinkAlpha(num,0.0,ALL_SIDES);
                    }
                }
            }
        }
}

if you have a LOT of child prims to set, and don't want to wait as long as it takes to loops through all those, an alternative would be to use LINK_ALL_OTHERS, from one that won't change, to set all the rest, and then set your other exceptions back to normal via targeting...depending on the object it might be a cleaner solution.

eg
llSetLinkTexture( LINK_ALL_OTHERS, newTexture, ALL_SIDES );
llSetLinkTexture( exceptionPrimInteger, exceptionDefaultTexture, ALL_SIDES );

True. As usual, though, once I got thinking about the OP's question I became more intrigued with a side issue. Leaving aside the immediate problem, then,...... If I wanted to use the Description field in a set of linked prims to carry multiple flags -- as I chose to do in my little script -- is there a neater way to parse the flags out of that field than this ....

list desc = llParseString2List(llList2String(llGetObjectDetail s(llGetLinkKey(num),[OBJECT_DESC]),0),[","],[""]);
if(llListFindList(desc,["texture"]) != -1)
// And so forth

?

It just seems clunky to take a list, convert it to a string, break it into parts and convert it back to a list, and then search the list to see if it contains one of the flags. But maybe that's the best way?

it'll probably look cleaner if you split it up, but i dunno if it'll be faster/slower than the way you have it. unfortunately, using a list is the only way to get the description from a different prim, which is why i went the name route. which you still could with your script as long as, like i said, the names of the child prims don't matter

maybe this.....

list desc = llParseString2List(llList2String(llGetObjectDetails(llGetLinkKey(num),[OBJECT_DESC]),0),[","],[""]);
if(llListFindList(desc,["texture"]) != -1)
// And so forth

could be.....

string desc = llList2String(llGetObjectDetails(llGetLinkKey(num),[OBJECT_DESC]),0);
if(llSubStringIndex(desc,"texture") != -1)
// And so forth

edited to remove some syntax errors what would have shown up with the snippet

Not bad... That's a little shorter. I'll test and see if it works. Thanks!

Thank you for the suggestions people, great stuff!