Gestures

Sry if this is in the wrong place, but I need some help Maybe one of you can shed some light on this for me.

I have been making Gestures with sounds that I have made myself. I was told some are very good and should be sold in my shop. The problem is this, I want to place my gestures into a box that one can click and have it animate them to see if they will like it. I have seen a few gesture retailers with this ability.

I searched the scripting library and also just did a basic search on Animators, bit to no avail. I would make the script myself, but, well, I don't know how to. Haha.

Even if someone hase to make something like this for me, I will pay you for it.

I am looking to get these in my shop ASAP!!

THANKS!!!
Lilly

Wow I was going to ask the very same question. There must be some way, because some people are doing it.

If someone wanted to hold a small class on doing this, I would be willing to pay a bit for it.


A proud member of PIC = Pudding Inner Core
__________________

Its pretty much the same concept as the posing stands people use for modeling. Basically its a block you "sit" on and it stops your sitting animation and starts a new one. I'll code up a good user friendly version of this tonight and post it here.

Ooh thanks Stone, I happily await your coding. How does one package a gesture though?

__________________________
"To announce that there must be no criticism of
the president, or that we are to stand by the
president right or wrong, is not only unpatriotic and
servile, but is morally treasonable to the
American public."
--Theodore Roosevelt

Here's the code free of charge, let me know if you'd like some improvements/adjustments.

This script is designed primarily for a floating ball that you click on and it starts the animation/sound. I dont have any type of purchase coding in this one, its just for previewing an animation, I'll leave the sales part up to the vendor.

Just set the options how you want them in the top of the script and change the "your_animation" to the name of the animation in the objects inventory. (Case sensitive).

Thats about as dummy proof as I can get short of a dialog menu to set it up. =P

/////////////////////////////////////////////////////////////////
//  Posing shop script by: Stone Mason
//  (Its been made countless times I know.)
//  Copy, edit, sell it, delete it, I dont care.
//  (Just dont blame me for anything that goes wrong.)
/////////////////////////////////////////////////////////////////
string gAnimation = "your_animation";
//Change to the name of your animation in the objects inventory.

integer gUseSound = FALSE;
//Change to TRUE if you want to play a sound with your animation.

string gSound = "your_sound";
//If you want to play a sound add it to the objects inventory and change to "sounds_name".

string gFloatingText = "floating_text";
//The floating text above the object.

string gSitText = "sit_text";
//What you want the pie chart to say instead of "sit".  i.e. "Demo"

integer gAvatarHeight = 0;
//How far up or down you want to adjust the posing avatars position.

integer gTimeToReset = 10;
//Length of time before the object kicks the poser off and resets.
//(Just here in case somebody goes afk while posing in your shop)

vector gBallColor = <1,0,0>;
//Sets the normal mode color of the prim. Numbers range from 0 to 1, in order they are %red, %green, %blue.
//Red = <1,0,0>  Green = <0,1,0>  Blue = <0,0,1>  <1,0.5,0> = Orange... etc etc..

float gNormalAlpha = 1.0;
//The normal mode alpha, 1.0 is fully opaque, 0.1 is almost completely transparent.

float gAnimationAlpha = 0.1;
//The animation mode alpha used when an animation is running.  1.0 is fully opaque, 0.1 is almost completely transparent.


default
{
    state_entry()
    {
        llSitTarget(<0,0,gAvatarHeight + 0.1>, ZERO_ROTATION);  //Set the sit target with the specified height.
        llSetText(gFloatingText, <0,1,0>, 1);  //Turn on the floating text.
        llSetSitText(gSitText);  //Change the pie menu text to the specified message.
		llSetPrimitiveParams([PRIM_COLOR, ALL_SIDES, gBallColor, gNormalAlpha] );  //Sets the color and alpha to normal mode.
    } 
    on_rez(integer vRezInfo)
    {
        llResetScript();
    }
    changed(integer vChange)
    {
        if ( vChange & CHANGED_LINK )  //If I detect a change...
        {
            if (llAvatarOnSitTarget() != NULL_KEY)  //And the change is an avatar sitting on me.
            {
                llSetTimerEvent(gTimeToReset);  //Start the timer for reset.
                llRequestPermissions(llAvatarOnSitTarget(), PERMISSION_TRIGGER_ANIMATION);  //Get permission to start an animation.
            }
            else
            {
                llSetText(gFloatingText, <0,1,0>, 1);  //Otherwise make sure the floating text is still on.
				llSetPrimitiveParams([PRIM_COLOR, ALL_SIDES, gBallColor, gNormalAlpha] );  //Sets the color and alpha to normal mode.
            }
        }
    }
     run_time_permissions(integer vPermissions)
    {
        if (vPermissions & PERMISSION_TRIGGER_ANIMATION)  //Once I have animation permissions...
        {
            llStopAnimation("sit");  //Stop the sit animation.
            llStartAnimation(gAnimation);  //Start the new animation.
            if (gUseSound == TRUE)  //If playing a sound during animation is enabled...
            {
                llPlaySound(gSound, 1.0);  //Play it.
            }
            llSetText("", <0,1,0>, 1);  //Turn off the floating text.
			llSetPrimitiveParams([PRIM_COLOR, ALL_SIDES, gBallColor, gAnimationAlpha] );  //Changes alpha to animation mode.
        }
    }
    timer()
    {
        if (llAvatarOnSitTarget() != NULL_KEY)  //Once the reset timer goes off...
        {
            llStopAnimation(gAnimation);  //Stop the animation we were playing..
            llUnSit(llAvatarOnSitTarget());  //Kick the avatar off me.
        }
        llSetTimerEvent(0);  //Turn off the timer.
        llSetText(gFloatingText, <0,1,0>, 1);  //Turn the floating text back on.
		llSetPrimitiveParams([PRIM_COLOR, ALL_SIDES, gBallColor, gNormalAlpha] );  //Sets the color and alpha to normal mode.
    }
}

I coded this at work with just a few minor bug checks so dont hold an error or two against me.

EDIT: From playing around, looks like you just have to make the gesture and distribute just that. As for previewing it, you'll have to use a seperate animation and sound on the block since I dont think there is any way to trigger a gesture from script (somebody correct me if I'm wrong.)

As for packaging, INVENTORY - CREATE - NEW GESTURE, then double click it and set it up.

LOL, wow that was easy. Thanks, now I'm off to try your script. Thanks.

__________________________
"To announce that there must be no criticism of
the president, or that we are to stand by the
president right or wrong, is not only unpatriotic and
servile, but is morally treasonable to the
American public."
--Theodore Roosevelt