Library: High Altitude Rezzer

Some interest in the forums lately about what you can do at elevations over 768 meters. This script allows you to rez an object and have a little privacy at elevations up to 4,096 meters. Pretty simple, instructions in script, no magic.

Enjoy!

//High Altitude Rezzer
//Creator: Jesse Barnett
//This script has been released to the script library in both wikis and the forums. Please do not sale this script! Be nice!
//Create something pretty to put this script in and to sit on. Place the script inside along with the object which you wish to rez.
//Sit on your beautiful creation and then touch it to ascend to the height you set below where it will rez your object. Stand up
//walk around, enjoy. When you want to return to where you started then just sit on it, delete your rezzed object and touch again.

integer target_height = 4090;//Set the elevation you want to go to here. Maximum you can rez objects is 4096.
float zSpeed = 500.0;
vector x;
vector w;
list grnd;
vector ground;
vector rez_obj_offset = <0.0, 0.0, -0.5>;//Adjust this as necessary for postion of 
																	//rezzed object in relation to vehicle. (no more then 10.0 in any axis)

default{
    on_rez(integer start_param) {
        llResetScript();
    }
    state_entry(){
        grnd = [];
        grnd += llGetPos();
        ground = llList2Vector(grnd, 0);
        vector pos = llGetPos();
        llSetStatus(STATUS_ROTATE_X | STATUS_ROTATE_Y | STATUS_ROTATE_Z, FALSE); 
        if(pos.z >= (target_height - 5)){
            state descend;
        }
        llSetText("Sit and touch to ascend", <0,0,0>,1.0);
    }
    touch_start(integer total_number){
       llSetStatus(STATUS_PHYSICS, TRUE);
        x = llGetPos();
        x.z = target_height;
        llTarget(x,50);
    }

    not_at_target(){
        llApplyImpulse(llGetMass()*<0,0,zSpeed>,FALSE);  
    }

    at_target(integer ascend, vector target, vector cPos){
        llTargetRemove(ascend);
        llMoveToTarget(target,1); 
        llSetTimerEvent(5.0);
    }

    timer(){
        vector pos = llGetPos();
        if(pos.z >= (target_height - 1)){
            llStopMoveToTarget();
            llApplyImpulse(-llGetMass()*llGetVel(),FALSE); 
            llSetStatus(STATUS_PHYSICS, FALSE);
            llRezObject(llGetInventoryName(INVENTORY_OBJECT, 0), llGetPos() + rez_obj_offset, ZERO_VECTOR, ZERO_ROTATION, 42);
            state descend;
       }
    }
}
state descend{
    state_entry() {
        vector pos = llGetPos();
        llSetStatus(STATUS_ROTATE_X | STATUS_ROTATE_Y | STATUS_ROTATE_Z, FALSE); 
        if(pos.z <= (ground.z + 5)){
            state default;
        }
        llSetText("Sit and touch to descend", <0,0,0>,1.0);
    }
    touch_start(integer total_number){
         llSetStatus(STATUS_PHYSICS, TRUE);
        w = llGetPos();
        w.z = ground.z;
        llTarget(w,50);
    }

    not_at_target(){
        llApplyImpulse(llGetMass()*<0,0,-500>,FALSE);  
    }

    at_target(integer descend, vector target2, vector Pos){
        llTargetRemove(descend);
        llMoveToTarget(target2,1); 
        llSetTimerEvent(5.0);
    }
    
    timer(){
        vector pos = llGetPos();
        if(pos.z <= (ground.z + 1)){
            llStopMoveToTarget();
            llApplyImpulse(-llGetMass()*llGetVel(),FALSE); 
            llSetStatus(STATUS_PHYSICS, FALSE);
            llSetPos(ground);
            state default;

       }
    }
}

I have been playing with high altitude objects lately, but kinda gave up. I used a rezzer with another script inside to move the rezzer upto about 4000m, when up to the correct altitude, i manually activate the rezzer and my platform rezzed. All was well and good, things seemed stable enough considering the altitude, but whilst i was offline, the platform and rezzer dissapeared.

I rezzed the platform again, and yet again all seemed well. Then it dissapeared again. I worked out that when the sim restarted my platform would just vanish and didnt even go into my lost and found folder. I have estate manager status, so i actually tested when the sim was empty, and after the restart, the platform had dissapeared.

Has anyone had anything similar happen?

It happens all of the time. Objects are not supposed to exist above the maximum build height of 768 meters. The ability to rez up to 4096 meters is a loop hole only. Sim restarts and it doesn't look for or recognise that there should be anything above 768.

As it stands now, this loop hole may be plugged when Havoc 4 hits the main grid. As it is set up in the beta grid now, the max build height has been raised to 1,024 meters but NOTHING can be rezzed above that height. We will have to wait to see the fate of high altitude rezzing.

this may help you...
/8/87/209746/1.html

it seems items over X height aren't stored for reboot, and simply dropped

Thanks for the info I'm gonna wait for Havok4 before playing with high altitude stuff again.