TP for more than 1000 mtr

As you now can build at higher altitudes I need a TP to a location at 4000 mtr. I tried to change 768 into 4096 (new maximum) in some TP-scripts I have found but it seems to be not possible to tp more than 1000 mrt???? Of course I can use LM's but I would prefer a tp without showing a map. Any tips?

Hmm. I imagine if build works that high then non-physical movement should as well. You've tried a "WarpPos" type teleporter?

I came across this old script put together by someone, doesn't hurt to see if it still works.

http://lsl.dimentox.com/snippet.php?sid=37

LM's, slurls & http addresses will only bring you to 1000 meters.

Here is an updated warpPos that works to 4096:

//////////////////////////////////////////////////////////////////////////////////////////////////////
//				Multi-HUD WarpPos 
// 				"Apr 23 2008", "14:36:26"
// 				Creator: Jesse Barnett
//				Released into the Public Domain
//////////////////////////////////////////////////////////////////////////////////////////////////////
 
integer listenId;	// Listener ID
key gAvatarID;
vector target;	// The location the av will be teleported to.
 
warpPos(vector target)
{	//R&D by Keknehv Psaltery, 05/25/2006
	//with a little pokeing by Strife, and a bit more
	//munging by Talarus Luan
	//Final cleanup by Keknehv Psaltery
	//and of course Jesse Barnett got to jump in here
	//and made it work up to 4096 meters
	//Fail safe removed
	// Compute the number of jumps necessary
	integer jumps = (integer) (llVecDist(target, llGetPos()) / 10.0) + 1;
	if (jumps > 206)
		jumps = 206;
	list rules =[PRIM_POSITION, target];	//The start for the rules list
	integer count = 1;
	while ((count = count << 1) < jumps)
		rules = (rules =[]) + rules + rules;	//should tighten memory use.
	llSetPrimitiveParams(rules + llList2List(rules, (count - jumps) << 1, count));
}
default {
	state_entry() {
		llSetObjectName("WarpPos");
	}
	listen(integer channel, string name, key id, string message) {
		target = (vector) message;
		llListenRemove(listenId);
		llSetText("Touch to teleport", <1, 1, 1 >, 1);
		llSitTarget(<0, 0, 0.5 >, ZERO_ROTATION);
	}
	on_rez(integer start_param) {
		// When this object rezzes setup a listener to get the target
		listenId = llListen(start_param, "", "", "");
	}
	changed(integer change) {
		if (change & CHANGED_LINK) {
			gAvatarID = llAvatarOnSitTarget();
			if (gAvatarID != NULL_KEY) {
				integer jumps = (integer) (llVecDist(target, llGetPos()) / 10.0) + 1;
				if (jumps > 206) {
					integer loops = jumps / 206;
					if (loops > 2) loops = 2;
					while (loops > 0) {
						loops--;
						warpPos(target);
					}
				}
			warpPos(target);
			llSleep(0.5);
			llDie();
			}
		}
	}
}

Thanks for the warpPos. No time now so I will try it tomorrow. But LM's do work above 1000, even to 4096! I didn't check SLURLS or HTTP addresses

ah I checked slurls and http but didn't check LMs But I hate LMs anyways, pain to dig through so many and I never have time to organize. So I created a slurl tp to use now added in warpPos for up higher.

EDIT: Forgot to mention that I fully expect slurls to catch up with the newer limits at some point or another.

Sorry for the mini-hijack (and also sorry if this has already been discussed elsewhere), but does anyone know if setting Home works up to 4096, and if it depends on the client version used? Thanks in advance.