Sell only to group members

I'm trully sorry about questioning this (I remember someone asked that but I can't fin'd the thread)

I want to put something on my shop to sell only to my group members, how do I do that? create a prim, put the item... and then?...

You can't do this by using any of the options in the Object Edit dialog. In order to do what you want you need a script that accepts money events and then checks whether the person paying is in your group. (Also note that they need to actually be wearing the group tag for this to work.) The script can then refund the person if they're not wearing the group tag, or give them the item otherwise.

Get a vendor that has a group discount. the make the regular price stupid high and the group discount price the real price.

I do that with my texture browsers that I set up for people to check out the stuff that is available but not just to anybody.

ok, ty... but there is no free script out there?

The best things in life are free, but not all scripts.

check the scripting tips forum

I've seen vendors set up to do this, both give a group discount and sell only to group members. Sadly, at the moment, I can't be certian where.

You might try Essensual Designs. They had vendors for sale like this at one time because they use a set-up like that to give gifts and discounts to their members. You could pop in there and have a look.

I believe all the major vendors have this option handy. hippoVEND certainly does.

Here:

   integer price = 250; // cost of item
   string object = "NameOfObject"; // Name of object being sold.
   
   default
   {
   	 state_entry()
   	 {
   		  llRequestPermissions(llGetOwner(), PERMISSION_DEBIT);
   	 }
   
   	 run_time_permissions(integer p)
   	 {
   		  if( p & PERMISSION_DEBIT)
   		  {
   			   llSetObjectDesc(object + " costs " + (string)price + "L$. Right-click and select 'pay' to purchace");
   			   llSetPayPrice(PAY_HIDE, [price, PAY_HIDE, PAY_HIDE, PAY_HIDE]);
   		  }
   		  else
   		  {
   			   state suspend;
   		  }
   	 }
   
   	 money(key id, integer amt)
   	 {
   		  if(amt != price || !llSameGroup(id))
   		  {
   			   llGiveMoney(id, amt);
   			   if(!llSameGroup(id)) llWhisper(0, "Remeber to be wearing your group tags!");
   			   if(amt != price) llWhisper(0, "Price is: " + (string)price + "L$.");
   		  }
   		  else
   		  {
   			   llGiveInventory(id, object);
   			   llWhisper(0, "Thanks for buying!");
   		  }
   	 }
   
    	 touch_start(integer n)
    	 {
    		  if(llDetectedKey(0) == llGetOwner())
    	  	 {
    	  	  	 llResetScript();
    	  	 }
    	  	 else
    	  	 {
    	  	  	 llWhisper(0, object + " costs " + (string)price + "L$.");
    	  	  	 if(!llDetectedGroup(0)) llWhisper(0, "Only available to our group. Wear your group tag to purchace.");
    	  	 }
    	 }

 	 on_rez(integer z)
 	 {
 	  	 llResetScript();
 	 }
   }
   
   state suspend
   {
  	 state_entry()
  	 {
  	  	 llSetObjectDesc("Vendor Suspended.");
  	 }
 
   	 touch_start(integer n)
   	 {
   		  if(llDetectedKey(0) == llGetOwner()) llResetScript();
   	 }
 
  	 on_rez(integer z)
  	 {
  	  	 llResetScript();
  	 }
   }

Untested, typed while groggy with meds. But, it should get you started.

TY Jillian

I just sent you a gift ty once again