Help please! Gift giver / group joiner needed

Hi there,

I am looking for a sign or board i can put my own logo on that gives group members only a free gift. I have found a few in xstreet but they all seem to come with the maker's logo. I am really trying to find something that can be tailored specifically for my sim.

The aims of the board are two-fold. Firstly I want to reward my current group members for their loyalty by giving them gifts, say a new one each month. Secondly, I hope to increase my overall numbers by attracting new members. As such, group members are to be given the gift as soon as they click the board. On the other hand, when non-members click the sign I need the script to direct them to join my group via a chat message (including Ctrl H suggestion to get the url).

Also, limiting each gift to one per group member would be handy or, alternatively, enabling the sign to give a gift with copy/mod, but no transfer rights. This may prevent members needlessly accessing multiple copies of a particular gift.

It would also need some sort of reset option so, when i add a new gift, it is given to members who have been given gift/s before. A space on the board where i can show an image of the gift would also be great.

Hope this all makes sense.

Looking forward to your replies.

Thanks,
Carmsie

I use the HippoTech hippoGroups..... the boards are mod so you can change the image to anything you like. You have multiple options.. you can give everyone a gift when they join... plus you can send everyone that has joined a gift at any time... along with notices.

Below is a dopey little script I hacked up to avoid doing anything actually productive.

You can just put it and anything you want to give into the contents of some prim and it becomes a gift giver / group joiner thing (with the Control-H version of group joining, as opposed to a bot-generated invite). You'll want to edit the stuff above the scary comment about "END OF STUFF...." (I took a guess at which group the OP had in mind, so that may be right for one person, once, without changing. )

I didn't bother using script memory to record who has already gotten the gift because, really, nobody gives transfer-permitted items (defeats the incentive of getting people to join the group and come get the gift), and if it's no-transfer, it may as well be copiable (and will be, unless the item and its contents have different permissions).

To get the script properly formatted, pretend to Quote this post, and copy the part between the php tags from that quoted text.

// Group gift / join script released into public domain by Qie Niangao, 2009.

key GROUP_KEY = "ba66f4d4-1473-11b4-c804-f8acf3aa4141";
// Get the GROUP_KEY from its web page, found with
// Search / All or from
// http://search.secondlife.com/web/search/groups/?q="Group Name"
// At the bottom of the group's web page is its URL,
// the end of the URL is the group's key.

string GIVING_MSG = "Thanks for your interest, and please enjoy your gift!";

string JOIN_MSG = "You need to be a member of the group to get the gift.  If you're not a member, type Control-H to get the chat history, and click on the following blue-highlighted text, then Join.  ";

string NOT_ACTIVE_MSG = "Or perhaps you're already a member and just don't have this group active at the moment; if so, click on the following text, choose the group from the list, and Activate.  ";

string FOLDER_NAME = "Gift from Group Name";

// ____________________________________________
// END OF STUFF MOST USERS WOULD WANT TO CHANGE
// --------------------------------------------

string GROUP_URI = "secondlife:///app/group/";
list giftContents;

default
{
    state_entry()
    {
        // In lieu of other specs, we'll just give everything in the object's inventory except this script
        // in a new folder named FOLDER_NAME.
        integer invIdx = llGetInventoryNumber(INVENTORY_ALL) - 1;
        string scriptName = llGetScriptName();
        for (; invIdx >= 0; invIdx--)
        {
            string invItemName = llGetInventoryName(INVENTORY_ALL, invIdx);
            if (invItemName != scriptName)
                giftContents += invItemName;
        }
        if ([] == giftContents)
            state no_contents;
        else
            llWhisper(0, "Will give folder named \"" + FOLDER_NAME + "\" containing these items: "
                + llDumpList2String(giftContents, ", "));
    }
    changed(integer change)
    {
        if (CHANGED_INVENTORY & change)
            llResetScript();
    }
    touch_start(integer total_number)
    {
        key toucher = llDetectedKey(0);
        if (llSameGroup(toucher))
        {
            llInstantMessage(toucher, GIVING_MSG);
            llGiveInventoryList(toucher, FOLDER_NAME, giftContents);
            return;
        }
        llInstantMessage(toucher, JOIN_MSG + GROUP_URI + (string)GROUP_KEY + "/about\n"
            + NOT_ACTIVE_MSG + GROUP_URI + "list/show");
    }
}

state no_contents
{
    state_entry()
    {
        llWhisper(DEBUG_CHANNEL, "Nothing to give; please add one or more gift items.");
    }
    changed(integer change)
    {
        if (CHANGED_INVENTORY & change)
            llResetScript();
    }
}

Thanks for that Qie I needed a script like that fo myself.

Thank you Qie!!!