Need help to find a script

i am looking for a script that when put inside a prim allows the prim to be touched and when people touch it their avatar name is recorded and then gives a message like "thank you for requesting an invite to blah blah group, the invite will be sent as soon as i can"


Abviously the script will also need to allow me to be able to get a copy o the names out somehow and wipe the names after i do


does anyone know of a script like this?? or is anyone able to script me something like this for not too much... i have only just opened a shop and i cant affoird much

I'm not a scripter, but I think you should look in the Script Library or Scripting Tips. I know others here in RA have suggested looking there. Maybe one of Torley Linden's tutorials has covered this subject, or you could suggest this be one of the future tutorials. You could also go to one of the NCI Centers and see who teaches the scripting classes, then drop a notecard to them asking for help or recommendations.

Or somebody who's more informed will come in and answer your question here in RA.

Good luck.



P.S. Look below Resident Answers in the next section and you'll see Script Library and Scripting Tips.

/advert on
Use this URL -
http://www.slexchange.com/modules.php?name=Marketplace&file=item&ItemID=449740
/advert off

There are loads of scripts like that out there. Some are more complex than others and the prices vary quite considerably.

We have such object for group invitation in our shop. If somebody clicked on it, it send a IM or eMail (or even both) with the name of the ava to you. It also can send a second eMail to another person.
If you don't find any script, call me ingame.

This is a pretty basic one, non of the frills but it should do what you need.

Change the first line to the message you wish to give when it is touched.

string greeting = " thank you for requesting an invite to blah blah group, the invite will be sent as soon as i can"; //message to say, avator name will be added to the front


list names = [];
key owner = NULL_KEY;
key touched = NULL_KEY;
integer chan;
integer handle;

integer randInt(integer n)
{
     return (integer)llFrand(n + 1);
}

integer randIntBetween(integer min, integer max)
{
    return min + randInt(max - min);
}


add_name(string name)
{
    if(llListFindList(names, (list)name) == -1)
    {
        llWhisper(0, name + greeting);
        names += name;
    }
}

list_names()
{
    integer loop;
    integer number = llGetListLength(names);

    for(loop = 0; loop < number; ++loop)
    {
        llOwnerSay(llList2String(names, loop));
    }
}

clear_names()
{
    names = [];
    llOwnerSay("Names Cleared");
}

default
{
    state_entry()
    {
        owner = llGetOwner();
        chan = randIntBetween(-20000, -1000);
    }
    touch_start(integer total_number)
    {
        touched = llDetectedKey(0);
        if(touched == owner)
        {
            llSetTimerEvent(30.0);
            handle = llListen(chan, "", owner, "");
            llDialog(owner, "Select Option", ["List", "Clear"], chan);
        }
        else
        {
            add_name(llKey2Name(touched));
        }
    }

    listen(integer channel, string name, key id, string message)
    {
        if(message == "List")
        {
            list_names();
        }
        else if(message == "Clear")
        {
            clear_names();
        }
    }

    timer()
    {
        llSetTimerEvent(0.0);
        llListenRemove(handle);
    }

    on_rez(integer start_param)
    {
        llResetScript();
    }
}

I have one for you Eclectic, if you can wait until tonight.

thanks everyone i have found one which is suitable