Sign Up Board

I need a way for ppl it be able to put there name on a sign up board. Can this be done?

Normally I don't allow requests, but since there is such a high volume of people looking for a script similar to this, I thought I would allow it So lets go you script monkeys.

A BIG thanks to Arpie Perkins who helped me truncate my commentary to readable lengths in this script .

// Just doing some minor cosmetic changes here.
// Gotta be careful to not overdocument, unless its a tutorial you dont need to explain the language.
// Also naming the variables well will make the code self explanatory.

//Global variables go below:
list gWhoRegistered; //List of names

integer NOT_FOUND_IN_LIST = -1; //This is declared just to keep everything clear.

default
{
    state_entry()
    {
        llSay(0, "Registration script active.");

        //Passing llGetOwner() 
        //tells it to only listen for the owner of the object this script is on.
        llListen(0,"",llGetOwner(),"");
    }

    // When an avatar clicks on an object:
    touch_start(integer total_number)
    {
        //'total_number' represents the person(s) touching the object.
        //Since there can be many people touching the object, 
        //we need to check every instance of total_number.
        //To do this, we use a loop.

        llSay(0, "Touched, registering name.");
        
        integer i; // represents the instance of total_number we're checking against.
        
        for(i = 0; i < total_number; i++)
        {
            string name = llDetectedName(i); // get the name of the toucher that i represents
            
            //Test to see if name is already registered (already in the list)
            if(llListFindList(gWhoRegistered,[name]) == NOT_FOUND_IN_LIST)
            {
                gWhoRegistered += name; // adds name to the list
                
                llSay(0,"Thank you for registering " + name + ".");
            }
            else
            {
                llSay(0,name + " is already registered.");
            }
        }
    }
    
    // When an avatar or object says something.
    // It gives the channel of the message,the name of the message sender, 
    //the key (UUID) of the message sender, and the actual message.
    listen(integer channel, string name, key id, string message)
    {
        if(message == "clear")
        {
            gWhoRegistered = [];        //Clears the list.
            llSay(0,"List cleared.");   //Confirmation message.
        }
        else if(message == "list") 
        {
            //Cycle through all the elements of the list.
            //We do mostly the same thing here as we did in the 'touch_start' event.
            
            llSay(0,"Registered names:");
            integer i;
            
            for(i = 0; i < llGetListLength(gWhoRegistered); i++)
            {
                //llList2String() returns the element on gWhoRegistered at position i
                string name = llList2String(gWhoRegistered,i);
                
                //Says the index where name is at, as well as the name.
                //Add 1 to i because the list starts at 0, to make it easier to understand.
                llSay(0,(string)(i + 1)+ ": " + name);
            }

            llSay(0,"Done reading list."); //Confirmation message.
        }
    }
}

I hope this is what you needed!

-Chris

Thanks for the credit Chris, but it was all your work. I don't deserve it.

just what i needed, thanks!